1/* SPDX-License-Identifier: BSD-2-Clause */
2/*
3 * Copyright (c) 2014, STMicroelectronics International N.V.
4 * Copyright (c) 2016-2019, Linaro Limited
5 */
6
7#ifdef ARM32
8OUTPUT_FORMAT("elf32-littlearm")
9OUTPUT_ARCH(arm)
10#endif
11#ifdef ARM64
12OUTPUT_FORMAT("elf64-littleaarch64")
13OUTPUT_ARCH(aarch64)
14#endif
15
16ENTRY(_ldelf_start)
17SECTIONS {
18	.text : {
19		__text_start = .;
20		*(.text._ldelf_start)
21		*(.text .text.*)
22		*(.stub)
23		*(.glue_7)
24		*(.glue_7t)
25		*(.gnu.linkonce.t.*)
26		/* Workaround for an erratum in ARM's VFP11 coprocessor */
27		*(.vfp11_veneer)
28		__text_end = .;
29	}
30	.note.gnu.property : { *(.note.gnu.property) }
31        .plt : { *(.plt) }
32
33	.eh_frame : { *(.eh_frame) }
34	.rodata : {
35		*(.gnu.linkonce.r.*)
36		*(.rodata .rodata.*)
37	}
38	/* .ARM.exidx is sorted, so has to go in its own output section.  */
39	.ARM.exidx : { *(.ARM.exidx* .gnu.linkonce.armexidx.*) }
40	.ARM.extab : { *(.ARM.extab*) }
41        .ctors : { *(.ctors) }
42        .dtors : { *(.dtors) }
43	.dynsym : { *(.dynsym) }
44	.dynstr : { *(.dynstr) }
45	.hash : { *(.hash) }
46
47	/*
48	 * Relocation sections may be aligned on 4 or 8 bytes. With ALIGN(8)
49	 * we avoid any padding between __reloc_begin and the first relocation.
50	 */
51	. = ALIGN(8);
52	__reloc_begin = .;
53	.rel.got : { *(.rel.got) }
54	.rela.got : { *(.rela.got) }
55	.rel.text : { *(.rel.text) *(.rel.gnu.linkonce.t*) }
56	.rela.text : { *(.rela.text) *(.rela.gnu.linkonce.t*) }
57	.rel.data : { *(.rel.data) *(.rel.gnu.linkonce.d*) }
58	.rela.data : { *(.rela.data) *(.rela.gnu.linkonce.d*) }
59	.rel.rodata : { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
60	.rela.rodata : { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
61	.rel.dyn : { *(.rel.dyn) }
62	.rela.dyn : { *(.rela.dyn) }
63	.rel.ctors : { *(.rel.ctors) }
64	.rela.ctors : { *(.rela.ctors) }
65	.rel.dtors : { *(.rel.dtors) }
66	.rela.dtors : { *(.rela.dtors) }
67	.rel.init : { *(.rel.init) }
68	.rela.init : { *(.rela.init) }
69	.rel.fini : { *(.rel.fini) }
70	.rela.fini : { *(.rela.fini) }
71	.rel.bss : { *(.rel.bss) }
72	.rela.bss : { *(.rela.bss) }
73	.rel.plt : { *(.rel.plt) }
74	.rela.plt : { *(.rela.plt) }
75	__reloc_end = .;
76
77	/* Page align to allow dropping execute bit for RW data */
78	. = ALIGN(4096);
79
80	.dynamic : { *(.dynamic) }
81	.got : { *(.got.plt) *(.got) }
82
83	.data : { *(.data .data.* .gnu.linkonce.d.*) }
84	.bss : { *(.bss .bss.* .gnu.linkonce.b.* COMMON) }
85
86	/DISCARD/ : { *(.interp) }
87}
88