1/*
2 * Copyright (c) 2013-2021, ARM Limited and Contributors. All rights reserved.
3 *
4 * SPDX-License-Identifier: BSD-3-Clause
5 */
6
7#include <platform_def.h>
8
9#include <arch.h>
10#include <common/bl_common.h>
11#include <el3_common_macros.S>
12#include <lib/pmf/aarch64/pmf_asm_macros.S>
13#include <lib/runtime_instr.h>
14#include <lib/xlat_tables/xlat_mmu_helpers.h>
15
16	.globl	bl31_entrypoint
17	.globl	bl31_warm_entrypoint
18
19	/* -----------------------------------------------------
20	 * bl31_entrypoint() is the cold boot entrypoint,
21	 * executed only by the primary cpu.
22	 * -----------------------------------------------------
23	 */
24
25func bl31_entrypoint
26	/* ---------------------------------------------------------------
27	 * Stash the previous bootloader arguments x0 - x3 for later use.
28	 * ---------------------------------------------------------------
29	 */
30	mov	x20, x0
31	mov	x21, x1
32	mov	x22, x2
33	mov	x23, x3
34
35#if !RESET_TO_BL31
36	/* ---------------------------------------------------------------------
37	 * For !RESET_TO_BL31 systems, only the primary CPU ever reaches
38	 * bl31_entrypoint() during the cold boot flow, so the cold/warm boot
39	 * and primary/secondary CPU logic should not be executed in this case.
40	 *
41	 * Also, assume that the previous bootloader has already initialised the
42	 * SCTLR_EL3, including the endianness, and has initialised the memory.
43	 * ---------------------------------------------------------------------
44	 */
45	el3_entrypoint_common					\
46		_init_sctlr=0					\
47		_warm_boot_mailbox=0				\
48		_secondary_cold_boot=0				\
49		_init_memory=0					\
50		_init_c_runtime=1				\
51		_exception_vectors=runtime_exceptions		\
52		_pie_fixup_size=BL31_LIMIT - BL31_BASE
53#else
54
55	/* ---------------------------------------------------------------------
56	 * For RESET_TO_BL31 systems which have a programmable reset address,
57	 * bl31_entrypoint() is executed only on the cold boot path so we can
58	 * skip the warm boot mailbox mechanism.
59	 * ---------------------------------------------------------------------
60	 */
61	el3_entrypoint_common					\
62		_init_sctlr=1					\
63		_warm_boot_mailbox=!PROGRAMMABLE_RESET_ADDRESS	\
64		_secondary_cold_boot=!COLD_BOOT_SINGLE_CPU	\
65		_init_memory=1					\
66		_init_c_runtime=1				\
67		_exception_vectors=runtime_exceptions		\
68		_pie_fixup_size=BL31_LIMIT - BL31_BASE
69
70	/* ---------------------------------------------------------------------
71	 * For RESET_TO_BL31 systems, BL31 is the first bootloader to run so
72	 * there's no argument to relay from a previous bootloader. Zero the
73	 * arguments passed to the platform layer to reflect that.
74	 * ---------------------------------------------------------------------
75	 */
76	mov	x20, 0
77	mov	x21, 0
78	mov	x22, 0
79	mov	x23, 0
80#endif /* RESET_TO_BL31 */
81
82	/* --------------------------------------------------------------------
83	 * Perform BL31 setup
84	 * --------------------------------------------------------------------
85	 */
86	mov	x0, x20
87	mov	x1, x21
88	mov	x2, x22
89	mov	x3, x23
90	bl	bl31_setup
91
92#if ENABLE_PAUTH
93	/* --------------------------------------------------------------------
94	 * Program APIAKey_EL1 and enable pointer authentication
95	 * --------------------------------------------------------------------
96	 */
97	bl	pauth_init_enable_el3
98#endif /* ENABLE_PAUTH */
99
100	/* --------------------------------------------------------------------
101	 * Jump to main function
102	 * --------------------------------------------------------------------
103	 */
104	bl	bl31_main
105
106	/* --------------------------------------------------------------------
107	 * Clean the .data & .bss sections to main memory. This ensures
108	 * that any global data which was initialised by the primary CPU
109	 * is visible to secondary CPUs before they enable their data
110	 * caches and participate in coherency.
111	 * --------------------------------------------------------------------
112	 */
113	adrp	x0, __DATA_START__
114	add	x0, x0, :lo12:__DATA_START__
115	adrp	x1, __DATA_END__
116	add	x1, x1, :lo12:__DATA_END__
117	sub	x1, x1, x0
118	bl	clean_dcache_range
119
120	adrp	x0, __BSS_START__
121	add	x0, x0, :lo12:__BSS_START__
122	adrp	x1, __BSS_END__
123	add	x1, x1, :lo12:__BSS_END__
124	sub	x1, x1, x0
125	bl	clean_dcache_range
126
127	b	el3_exit
128endfunc bl31_entrypoint
129
130	/* --------------------------------------------------------------------
131	 * This CPU has been physically powered up. It is either resuming from
132	 * suspend or has simply been turned on. In both cases, call the BL31
133	 * warmboot entrypoint
134	 * --------------------------------------------------------------------
135	 */
136func bl31_warm_entrypoint
137#if ENABLE_RUNTIME_INSTRUMENTATION
138
139	/*
140	 * This timestamp update happens with cache off.  The next
141	 * timestamp collection will need to do cache maintenance prior
142	 * to timestamp update.
143	 */
144	pmf_calc_timestamp_addr rt_instr_svc, RT_INSTR_EXIT_HW_LOW_PWR
145	mrs	x1, cntpct_el0
146	str	x1, [x0]
147#endif
148
149	/*
150	 * On the warm boot path, most of the EL3 initialisations performed by
151	 * 'el3_entrypoint_common' must be skipped:
152	 *
153	 *  - Only when the platform bypasses the BL1/BL31 entrypoint by
154	 *    programming the reset address do we need to initialise SCTLR_EL3.
155	 *    In other cases, we assume this has been taken care by the
156	 *    entrypoint code.
157	 *
158	 *  - No need to determine the type of boot, we know it is a warm boot.
159	 *
160	 *  - Do not try to distinguish between primary and secondary CPUs, this
161	 *    notion only exists for a cold boot.
162	 *
163	 *  - No need to initialise the memory or the C runtime environment,
164	 *    it has been done once and for all on the cold boot path.
165	 */
166	el3_entrypoint_common					\
167		_init_sctlr=PROGRAMMABLE_RESET_ADDRESS		\
168		_warm_boot_mailbox=0				\
169		_secondary_cold_boot=0				\
170		_init_memory=0					\
171		_init_c_runtime=0				\
172		_exception_vectors=runtime_exceptions		\
173		_pie_fixup_size=0
174
175	/*
176	 * We're about to enable MMU and participate in PSCI state coordination.
177	 *
178	 * The PSCI implementation invokes platform routines that enable CPUs to
179	 * participate in coherency. On a system where CPUs are not
180	 * cache-coherent without appropriate platform specific programming,
181	 * having caches enabled until such time might lead to coherency issues
182	 * (resulting from stale data getting speculatively fetched, among
183	 * others). Therefore we keep data caches disabled even after enabling
184	 * the MMU for such platforms.
185	 *
186	 * On systems with hardware-assisted coherency, or on single cluster
187	 * platforms, such platform specific programming is not required to
188	 * enter coherency (as CPUs already are); and there's no reason to have
189	 * caches disabled either.
190	 */
191#if HW_ASSISTED_COHERENCY || WARMBOOT_ENABLE_DCACHE_EARLY
192	mov	x0, xzr
193#else
194	mov	x0, #DISABLE_DCACHE
195#endif
196	bl	bl31_plat_enable_mmu
197
198#if ENABLE_RME
199	/*
200	 * At warm boot GPT data structures have already been initialized in RAM
201	 * but the sysregs for this CPU need to be initialized. Note that the GPT
202	 * accesses are controlled attributes in GPCCR and do not depend on the
203	 * SCR_EL3.C bit.
204	 */
205	bl	gpt_enable
206	cbz	x0, 1f
207	no_ret plat_panic_handler
2081:
209#endif
210
211#if ENABLE_PAUTH
212	/* --------------------------------------------------------------------
213	 * Program APIAKey_EL1 and enable pointer authentication
214	 * --------------------------------------------------------------------
215	 */
216	bl	pauth_init_enable_el3
217#endif /* ENABLE_PAUTH */
218
219	bl	psci_warmboot_entrypoint
220
221#if ENABLE_RUNTIME_INSTRUMENTATION
222	pmf_calc_timestamp_addr rt_instr_svc, RT_INSTR_EXIT_PSCI
223	mov	x19, x0
224
225	/*
226	 * Invalidate before updating timestamp to ensure previous timestamp
227	 * updates on the same cache line with caches disabled are properly
228	 * seen by the same core. Without the cache invalidate, the core might
229	 * write into a stale cache line.
230	 */
231	mov	x1, #PMF_TS_SIZE
232	mov	x20, x30
233	bl	inv_dcache_range
234	mov	x30, x20
235
236	mrs	x0, cntpct_el0
237	str	x0, [x19]
238#endif
239	b	el3_exit
240endfunc bl31_warm_entrypoint
241